# Maintainer: Nils Briggen <nilsbriggen@gmail.com>
pkgname=slidewire
pkgver=1.0.0
pkgrel=1
pkgdesc="Control application and device volumes with a MIDI controller"
arch=(x86_64 aarch64)
url="https://git.briggen.dev/NilsBriggen/SlideWire"
license=(GPL-3.0-or-later)
depends=(alsa-lib libpulse gcc-libs glibc dbus libxkbcommon wayland libglvnd)
makedepends=(cargo)
optdepends=(
  'libx11: X11 session support'
  'libxcursor: X11 session support'
  'libxi: X11 session support'
  'libxrandr: X11 session support'
  'easyeffects: EasyEffects preset buttons'
  'ydotool: key-combination buttons'
)
conflicts=(slidewire-git)
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha256sums=(SKIP)

prepare() {
  cd "$pkgname"
  export RUSTUP_TOOLCHAIN=stable
  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
  cd "$pkgname"
  export RUSTUP_TOOLCHAIN=stable
  export CARGO_TARGET_DIR=target
  export RUSTFLAGS="${RUSTFLAGS:-} --remap-path-prefix=$srcdir=/usr/src/debug/$pkgname"
  cargo build --frozen --release
}

check() {
  cd "$pkgname"
  export RUSTUP_TOOLCHAIN=stable
  cargo test --frozen --release
}

package() {
  cd "$pkgname"
  scripts/install.sh "$pkgdir"
}